<%@language="VBScript"%>
<% Response.Expires = -1 %>
<!--#include file="inc/kontrola-prihlaseni.asp" -->
<!--#include file="inc/conn.asp" -->
<% 
function entity(obsah)
	if isnull(obsah) = false then
		obsah = replace(obsah,"&","&amp;")
		obsah = replace(obsah,"""","&quot;")
		obsah = replace(obsah,"<","&lt;")
		obsah = replace(obsah,">","&gt;")
		entity = obsah
	end if
end function

'funkce - vyseparování údajů z objednávky
function value(nazev)
	seznam = zakaznik
	if instr(seznam,nazev) > 0 then
		pozice1 = instrrev(seznam, nazev) + len(nazev)
		pozice2 = instr(pozice1,seznam,"&")
		hodnota = mid(seznam, pozice1, pozice2 - pozice1)
		if not hodnota = "" then
			value = hodnota
		end if
	end if
end function




Server.ScriptTimeout = 300
set f = server.createobject("scripting.filesystemobject")
if request("xml") = "xml_stormware" then
	set soubor = f.CreateTextFile(Server.MapPath("xml/xml_stormware.xml"),true)
end if


soubor.WriteLine("<?xml version=""1.0"" encoding=""windows-1250""?>")
soubor.WriteLine("<dat:dataPack id=""pr001"" ico=""61875368"" application=""StwTest"" version=""2.0"" note=""Import prodejky"" xmlns:dat=""http://www.stormware.cz/schema/version_2/data.xsd"" xmlns:pro=""http://www.stormware.cz/schema/version_2/prodejka.xsd"" xmlns:typ=""http://www.stormware.cz/schema/version_2/type.xsd"">")


start = 0
Set rs = CreateObject("ADODB.RecordSet")
strSQL = "SELECT * FROM s_prodejka WHERE id_s_prodejka IN (" & left(session("prodejky_vyber"),len(session("prodejky_vyber"))-1) & ")"
rs.Open strSQL, conn, 1, 1
do while not rs.eof
	start = start + 1
	'response.write start & ", "
	response.write rs("id_s_prodejka") & ", "
	
	'zákazník
	zakaznik = rs("zakaznik")
	fakturacni_adr = rs("fakturacni_adr")
	if fakturacni_adr = false then
		jmeno = value("jmeno=") & " " & value("prijmeni=")
		firma = value("firma2=")
		ulice = value("ulice2=")
		mesto = value("mesto2=")
		psc = value("psc2=")
		if value("ico2=") <> "" then ico = value("ico2=") end if
		if value("dic2=") <> "" then dic = value("dic2=") end if
	else
		jmeno = value("jmeno3=")
		firma = value("firma3=")
		ulice = value("ulice3=")
		mesto = value("mesto3=")
		psc = value("psc3=")
		if value("ico3=") <> "" then ico = value("ico3=") end if
		if value("dic3=") <> "" then dic = value("dic3=") end if
	end if
	
	'druh platby
	if rs("id_platba") = 1 then
		platba = "cash"
	elseif rs("id_platba") = 2 then
		platba = "draft"
	elseif rs("id_platba") = 3 then
		platba = "delivery"
	else
		platba = "compensation" 'v případě splátek a jiného druhu platby
	end if
	
	'ceny
	cena_celkem = 0
	cena_celkem_dph0 = 0
	cena_celkem_dph1 = 0
	cena_celkem_dph2 = 0
	Set rs2 = CreateObject("ADODB.RecordSet")
	strSQL = "SELECT SUM(ROUND(s_prodejka2.cena - (s_prodejka2.cena/100 * s_prodejka2.sleva),1) * s_prodejka2.ks), MAX(s_prodejka2.dph), MAX(dph_prodej2) FROM s_prodejka2, s_zbozi WHERE id_s_prodejka = " & rs("id_s_prodejka") & " AND s_zbozi.id_s_zbozi = s_prodejka2.id_s_zbozi GROUP BY dph_prodej2"
	rs2.Open strSQL, conn, 1, 1
	do while not rs2.eof
		cena_celkem = rs2(0)
		dph = rs2(1)
		dph_druh = rs2(2)
		'přidání poštovného a balného do výpočtu dph
		if dph = rs("dph_postovne") then
			cena_celkem = cena_celkem + rs("postovne") + rs("balne")
		elseif rs2.recordcount = 1 and dph_druh = 2 then
			cena_celkem_dph1 = rs("postovne") + rs("balne")
		elseif rs2.recordcount = 1 and dph_druh = 1 then
			cena_celkem_dph2 = rs("postovne") + rs("balne")
		end if
		
		if dph = 0 then
			cena_celkem_dph0 = cena_celkem 'nulové dph
		elseif dph_druh = 2 then
			cena_celkem_dph2 = cena_celkem 'nízké dph
		elseif dph_druh = 1 then
			cena_celkem_dph1 = cena_celkem 'vysoké dph
		end if
		rs2.movenext
	loop
	rs2.close
	
	
	soubor.WriteLine("	<dat:dataPackItem id=""" & rs("kod") & """ version=""2.0"">")
	soubor.WriteLine("		<pro:prodejka version=""2.0"">")
	soubor.WriteLine("			<pro:prodejkaHeader>")
	soubor.WriteLine("				<pro:date>" & rs("datum_dph") & "</pro:date>")
	soubor.WriteLine("				<pro:text>Prodejka " & rs("kod") & "</pro:text>")
	soubor.WriteLine("				<pro:partnerIdentity>")
	soubor.WriteLine("					<typ:address>")
	soubor.WriteLine("						<typ:company><![CDATA[" & firma & "]]></typ:company>")
	soubor.WriteLine("						<typ:division><![CDATA[" & "" & "]]></typ:division>")
	soubor.WriteLine("						<typ:name><![CDATA[" & jmeno & "]]></typ:name>")
	soubor.WriteLine("						<typ:city><![CDATA[" & mesto & "]]></typ:city>")
	soubor.WriteLine("						<typ:street><![CDATA[" & ulice & "]]></typ:street>")
	soubor.WriteLine("						<typ:zip><![CDATA[" & psc & "]]></typ:zip>")
	soubor.WriteLine("						<typ:ico><![CDATA[" & ico & "]]></typ:ico>")
	soubor.WriteLine("						<typ:dic><![CDATA[" & dic & "]]></typ:dic>")
	soubor.WriteLine("					</typ:address>")
	soubor.WriteLine("				</pro:partnerIdentity>")
	soubor.WriteLine("				<pro:paymentType>")
	soubor.WriteLine("					<typ:ids>" & platba & "</typ:ids>")
	soubor.WriteLine("				</pro:paymentType>")
	soubor.WriteLine("			</pro:prodejkaHeader>")
	soubor.WriteLine("			<pro:prodejkaSummary>")
	soubor.WriteLine("				<pro:roundingDocument>" & "math2one" & "</pro:roundingDocument>") 'cenu zaokrouhlit na koruny
	soubor.WriteLine("				<pro:roundingVAT>" & "noneEveryRate" & "</pro:roundingVAT>") 'DPH nezaokrouhlovat
	soubor.WriteLine("				<pro:homeCurrency>")
	soubor.WriteLine("					<typ:priceNone>" & cena_celkem_dph0 & "</typ:priceNone>") 'částka s nulovym DPH - s DPH
	soubor.WriteLine("					<typ:priceHighSum>" & cena_celkem_dph1 & "</typ:priceHighSum>") 'částka s vysokym DPH - s DPH
	soubor.WriteLine("					<typ:priceLowSum>" & cena_celkem_dph2 & "</typ:priceLowSum>") 'částka s nízkym DPH - s DPH
	soubor.WriteLine("				</pro:homeCurrency>")
	soubor.WriteLine("			</pro:prodejkaSummary>")
	soubor.WriteLine("		</pro:prodejka>")
	soubor.WriteLine("	</dat:dataPackItem>")
	rs.movenext
loop
rs.close
conn.close


soubor.WriteLine("</dat:dataPack>")


response.clear
response.redirect "xml/xml_stormware.xml"
 %>