<%@language="VBScript"%>
<% Response.Expires = 0 %>
<% Response.charset = "iso-8859-2" %>
<!--#include file="../inc/kontrola.asp" --> 
<!--#include file="../inc/conn.asp" -->
<% 
'uložení xml souboru
Set objXML = CreateObject("MSXML2.ServerXMLHTTP")
objXML.open "POST", "http://napostu.ceskaposta.cz/vystupy/balikovny.xml", false
objXML.setRequestHeader "Content-Type", "text/plain;charset=iso-8859-2"
objXML.send()
If objXML.Status = 200 Then
	Set objStream = CreateObject("ADODB.Stream")
	objStream.Type = 1
	objStream.Open
	objStream.Write objXML.ResponseBody
	objStream.SaveToFile Server.MapPath("../xml") & "\balikovna.xml", 2
	objStream.Close
	Set objStream = Nothing
End if 
Set objXML = Nothing


'načtení xml a uložení do databáze
Set objXML = Server.CreateObject("MSXML2.DOMDocument.3.0")
objXML.async = False
objXML.load Server.MapPath("balikovna.xml")
conn.execute "DELETE FROM balikovna"
Set rs = CreateObject("ADODB.RecordSet")
rs.Open "balikovna", conn, 2, 3 + AdExecuteNoRecords
for each adresa in objXML.documentElement.selectNodes("row")
	rs.Addnew
	rs("nazev") = adresa.selectSingleNode("NAZEV").text
	rs("adresa") = adresa.selectSingleNode("ADRESA").text
	rs("typ") = adresa.selectSingleNode("TYP").text
	rs("obec") = adresa.selectSingleNode("OBEC").text
	rs("c_obce") = adresa.selectSingleNode("C_OBCE").text
	rs("sour_x") = adresa.selectSingleNode("SOUR_X").text
	rs("sour_y") = adresa.selectSingleNode("SOUR_Y").text
	rs("psc") = adresa.selectSingleNode("PSC").text
	rs.update
Next
rs.close
conn.close
Set objXML = Nothing
 %>